スポンサーリンク

2015年06月03日

Arduino で遊ぶ!BME280 にリアルタイムクロックを追加

今回は、気圧、湿度、温度計の試作第3弾です。
前回は、Arduino UNO の代わりに、安価なAVR マイコン ATmega328P-PU を使って測定データを LCD に表示させました

今回は前回の試作に、リアルタイムクロック(RTC)モジュール[RTC-8564NB]を追加しました。

RTC-8564NBは、秋月電子通商で販売(500円)販売されている物を使いました。
20150603120058.png
I/F:I2C
動作電圧:1.8V〜5.5V
消費電流:275nA(@ 3.0V、非アクセス時)
20150603122616.png
端子4:VSS
端子5:SDA
端子6:SCL
端子8:VDD

RTCの時間設定は、SET UP での設定です。
いずれ、LCDを見ながらの対話式設定にしたいと思っています。
データ測定は、1分毎。
1分の計測は、RTC8564のTimerFrag を1秒ごとに監視して行っています。

20150603125223.png

IMG_7669.JPG



Arduino IDE のバージョンは、1.0.5-r2 です。

#include <Wire.h>
#include <LcdCore.h>         // LCDコアライブラリ
#include <LCD_ACM1602NI.h>   // 秋月I2C液晶用のI/Oライブラリ
#include "RTC8564.h"
#include <avr/sleep.h>
#include <avr/wdt.h>

#ifndef cbi
#define cbi(sfr, bit) (_SFR_BYTE(sfr) &= ~_BV(bit))
#endif
#ifndef sbi
#define sbi(sfr, bit) (_SFR_BYTE(sfr) |= _BV(bit))
#endif

LCD_ACM1602NI lcd(0xa0); // 0xa0はI2Cアドレス

#define BME280_ADDRESS 0x76

unsigned long int hum_raw,temp_raw,pres_raw;
signed long int t_fine;

int interruptPin = 12;

uint16_t dig_T1;
 int16_t dig_T2;
 int16_t dig_T3;
uint16_t dig_P1;
 int16_t dig_P2;
 int16_t dig_P3;
 int16_t dig_P4;
 int16_t dig_P5;
 int16_t dig_P6;
 int16_t dig_P7;
 int16_t dig_P8;
 int16_t dig_P9;
 int8_t  dig_H1;
 int16_t dig_H2;
 int8_t  dig_H3;
 int16_t dig_H4;
 int16_t dig_H5;
 int8_t  dig_H6;

void setup()
{
    uint8_t osrs_t = 1;             //Temperature oversampling x 1
    uint8_t osrs_p = 1;             //Pressure oversampling x 1
    uint8_t osrs_h = 1;             //Humidity oversampling x 1
    uint8_t mode = 3;               //Normal mode
    uint8_t t_sb = 5;               //Tstandby 1000ms
    uint8_t filter = 0;             //Filter off
    uint8_t spi3w_en = 0;           //3-wire SPI Disable
   
    uint8_t ctrl_meas_reg = (osrs_t << 5) | (osrs_p << 2) | mode;
    uint8_t config_reg    = (t_sb << 5) | (filter << 2) | spi3w_en;
    uint8_t ctrl_hum_reg  = osrs_h;
   
    struct dateTime dt = {0, 47, 12, 3, 6, 15, 3};
    char s[20];
    uint8_t flags;
   

    Serial.begin(9600);
    Wire.begin();
    RTC8564.begin(&dt);
    RTC8564.setTimer(true, false, RTC8564_CLK_1MIN, 1, true);

    lcd.begin(16, 2);
    lcd.noCursor();
   
    writeReg(0xF2,ctrl_hum_reg);
    writeReg(0xF4,ctrl_meas_reg);
    writeReg(0xF5,config_reg);
    readTrim();                    //

}

void loop(){

  mesurement();

while(!RTC8564.getTimerFlag()) {
    delay(1000);
  }
    RTC8564.clearTimerFlag();
}  // loop

void mesurement()
{
    double temp_act = 0.0, press_act = 0.0,hum_act=0.0;
    int i_temp_act, i_hum_act;
    float f_temp_act, f_hum_act;
    signed long int temp_cal;
    unsigned long int press_cal,hum_cal; 
   
    struct dateTime dt;
    char s[20];
    uint8_t data;

      if (RTC8564.getDateTime(&dt) == 0) {
         sprintf(s, "%4d/%02d/%02d %02d:%02d:%02d ",
         dt.year, dt.month, dt.day, dt.hour, dt.minute, dt.second);
      } else {
        RTC8564.begin();
        Serial.println("Detected voltage low");
     }

    Serial.print(s);

    readData();
    temp_cal = calibration_T(temp_raw);
    press_cal = calibration_P(pres_raw);
    hum_cal = calibration_H(hum_raw);
    temp_act = (double)temp_cal / 100.0;
    press_act = (double)press_cal / 100.0;
    hum_act = (double)hum_cal / 1024.0;

    Serial.print("TEMP: ");
    Serial.print(temp_act);
    Serial.print("DegC  PRESS: ");
    Serial.print(press_act);
    Serial.print("hPa  HUM: ");
    Serial.print(hum_act);
    Serial.println("%");   
 
    lcd.clear();
    lcd.setCursor(0,0);
    if(press_act < 1000) lcd.print(" ");
    lcd.print(press_act);
    lcd.setCursor(7,0);
    lcd.print("hPa ");
   
    i_temp_act = temp_act * 10;
    f_temp_act = i_temp_act;
    f_temp_act = f_temp_act / 10;

    if(temp_act - f_temp_act >= 0.05) f_temp_act += 0.1;
       
    lcd.setCursor(2,1);
    lcd.print(f_temp_act);
   
    lcd.setCursor(6,1);
    lcd.write(0xDF);
    lcd.write(0x43);
 
    i_hum_act = hum_act * 10;
    f_hum_act = i_hum_act;
    f_hum_act = f_hum_act / 10;
    if(hum_act - f_hum_act >= 0.05) f_hum_act += 0.1;
   
    lcd.setCursor(11,1);
    lcd.print(f_hum_act);
    lcd.setCursor(15,1);
    lcd.print("%");
 
    lcd.setCursor(11,0);
    if(dt.hour < 10) lcd.setCursor(12,0);
    lcd.print(dt.hour,DEC); lcd.print(":");
    if(dt.minute < 10)  lcd.print(0);
    lcd.print(dt.minute);
}

void readTrim()
{
    uint8_t data[32],i=0;                     
    Wire.beginTransmission(BME280_ADDRESS);
    Wire.write(0x88);
    Wire.endTransmission();
    Wire.requestFrom(BME280_ADDRESS,24);     
    while(Wire.available()){
        data[i] = Wire.read();
        i++;
    }
   
    Wire.beginTransmission(BME280_ADDRESS);    // Add 2014/04/06
    Wire.write(0xA1);                         
    Wire.endTransmission();                  
    Wire.requestFrom(BME280_ADDRESS,1);       
    data[i] = Wire.read();                    
    i++;                                      
   
    Wire.beginTransmission(BME280_ADDRESS);
    Wire.write(0xE1);
    Wire.endTransmission();
    Wire.requestFrom(BME280_ADDRESS,7);       
    while(Wire.available()){
        data[i] = Wire.read();
        i++;   
    }
    dig_T1 = (data[1] << 8) | data[0];
    dig_T2 = (data[3] << 8) | data[2];
    dig_T3 = (data[5] << 8) | data[4];
    dig_P1 = (data[7] << 8) | data[6];
    dig_P2 = (data[9] << 8) | data[8];
    dig_P3 = (data[11]<< 8) | data[10];
    dig_P4 = (data[13]<< 8) | data[12];
    dig_P5 = (data[15]<< 8) | data[14];
    dig_P6 = (data[17]<< 8) | data[16];
    dig_P7 = (data[19]<< 8) | data[18];
    dig_P8 = (data[21]<< 8) | data[20];
    dig_P9 = (data[23]<< 8) | data[22];
    dig_H1 = data[24];
    dig_H2 = (data[26]<< 8) | data[25];
    dig_H3 = data[27];
    dig_H4 = (data[28]<< 4) | (0x0F & data[29]);
    dig_H5 = (data[30] << 4) | ((data[29] >> 4) & 0x0F);
    dig_H6 = data[31];                                 
}
void writeReg(uint8_t reg_address, uint8_t data)
{
    Wire.beginTransmission(BME280_ADDRESS);
    Wire.write(reg_address);
    Wire.write(data);
    Wire.endTransmission();   
}


void readData()
{
    int i = 0;
    uint32_t data[8];
    Wire.beginTransmission(BME280_ADDRESS);
    Wire.write(0xF7);
    Wire.endTransmission();
    Wire.requestFrom(BME280_ADDRESS,8);
    while(Wire.available()){
        data[i] = Wire.read();
        i++;
    }
    pres_raw = (data[0] << 12) | (data[1] << 4) | (data[2] >> 4);
    temp_raw = (data[3] << 12) | (data[4] << 4) | (data[5] >> 4);
    hum_raw  = (data[6] << 8) | data[7];
}


signed long int calibration_T(signed long int adc_T)
{
   
    signed long int var1, var2, T;
    var1 = ((((adc_T >> 3) - ((signed long int)dig_T1<<1))) * ((signed long int)dig_T2)) >> 11;
    var2 = (((((adc_T >> 4) - ((signed long int)dig_T1)) * ((adc_T>>4) - ((signed long int)dig_T1))) >> 12) * ((signed long int)dig_T3)) >> 14;
   
    t_fine = var1 + var2;
    T = (t_fine * 5 + 128) >> 8;
    return T;
}

unsigned long int calibration_P(signed long int adc_P)
{
    signed long int var1, var2;
    unsigned long int P;
    var1 = (((signed long int)t_fine)>>1) - (signed long int)64000;
    var2 = (((var1>>2) * (var1>>2)) >> 11) * ((signed long int)dig_P6);
    var2 = var2 + ((var1*((signed long int)dig_P5))<<1);
    var2 = (var2>>2)+(((signed long int)dig_P4)<<16);
    var1 = (((dig_P3 * (((var1>>2)*(var1>>2)) >> 13)) >>3) + ((((signed long int)dig_P2) * var1)>>1))>>18;
    var1 = ((((32768+var1))*((signed long int)dig_P1))>>15);
    if (var1 == 0)
    {
        return 0;
    }   
    P = (((unsigned long int)(((signed long int)1048576)-adc_P)-(var2>>12)))*3125;
    if(P<0x80000000)
    {
       P = (P << 1) / ((unsigned long int) var1);  
    }
    else
    {
        P = (P / (unsigned long int)var1) * 2;   
    }
    var1 = (((signed long int)dig_P9) * ((signed long int)(((P>>3) * (P>>3))>>13)))>>12;
    var2 = (((signed long int)(P>>2)) * ((signed long int)dig_P8))>>13;
    P = (unsigned long int)((signed long int)P + ((var1 + var2 + dig_P7) >> 4));
    return P;
}

unsigned long int calibration_H(signed long int adc_H)
{
    signed long int v_x1;
   
    v_x1 = (t_fine - ((signed long int)76800));
    v_x1 = (((((adc_H << 14) -(((signed long int)dig_H4) << 20) - (((signed long int)dig_H5) * v_x1)) +
              ((signed long int)16384)) >> 15) * (((((((v_x1 * ((signed long int)dig_H6)) >> 10) *
              (((v_x1 * ((signed long int)dig_H3)) >> 11) + ((signed long int) 32768))) >> 10) + (( signed long int)2097152)) *
              ((signed long int) dig_H2) + 8192) >> 14));
   v_x1 = (v_x1 - (((((v_x1 >> 15) * (v_x1 >> 15)) >> 7) * ((signed long int)dig_H1)) >> 4));
   v_x1 = (v_x1 < 0 ? 0 : v_x1);
   v_x1 = (v_x1 > 419430400 ? 419430400 : v_x1);
   return (unsigned long int)(v_x1 >> 12); 
}




posted by goro*goro at 13:21 | DIY | このブログの読者になる | 更新情報をチェックする


スポンサーリンク

×

この広告は180日以上新しい記事の投稿がないブログに表示されております。